迷走の果て・Tiny Objects

迷走する日々の覚え書きです。自分で分かってることは省略してますので、念のため。

2端子温度センサLMT01を試す(10)多チャンネル化・続き

LMT01のデータシートFig..33に複数のLMT01をつなぐ方法が載せられてます。

MUlitMLT01_datasheet.jpg
注意すべき点は使わないLMT01のVPはローレベルにするのではなくフローティングにすることです。
ローレベルにすると逆バイアスされるからです。

絶対最大定格です。逆バイアス許容値は0.3V、これは低いですねぇ。
最大規格LMT01

Arduinoでポートをフローティングにするには
pinMode(N , INPUT)
とします、Nはポート番号です。

ここでは2つのLMT01をつないで見ましたが、プログラムとしては

2つのポートをフローティングにしておく。

1つのポートを出力モードにしてHレベルを出力する、これで計測が開始されます。
温度測定が終わったらポートをフローティングにする。
他のポートも同様にして測定する。
の繰り返し。

とりあえずのスケッチです。
実験なのでパルス数も表示してます。

// LMT01をArduinoにつなぐ
// edy
//
// 2016/02/13:内部コンパレータを使う
// 2016/02/14:内部基準電圧を使う
// 2016/02/16:2つのLMT01を使う
//
//参考にしたサイト:コンパレータ割り込み minori246さん
//http://minori246.blog.fc2.com/blog-entry-15.html
//
//参考にしたサイト:パルス列終了検出 ラジオペンチさん 
//http://radiopench.blog96.fc2.com/blog-entry-640.html
//
#ifndef cbi
#define cbi(sfr, bit) (_SFR_BYTE(sfr) &= ~_BV(bit)) //clear
#endif
#ifndef sbi
#define sbi(sfr, bit) (_SFR_BYTE(sfr) |= _BV(bit)) //set
#endif

#include <LiquidCrystal.h>

LiquidCrystal lcd(4, 3, 8, 9, 10, 11); //LiquidCrystal(rs, enable, d4, d5, d6, d7)

volatile unsigned int count = 0;
unsigned int LASTcount = 0;
char s[16];
float temp;

void setup()
{
 pinMode(5, INPUT);
 pinMode(6, INPUT);
 lcd.begin(16, 2);
 initComp();
 lcd.setCursor(0, 0);
 lcd.print("Start LMT01");
 delay(1000);
 lcd.setCursor(0, 0);
 lcd.print("           ");
}

void loop()
{
 pinMode(5, OUTPUT);
 digitalWrite(5, 1); // D5をオンにしてLMT01-no.1をスタート
 delay(1);
 countpulse();
 dtostrf(count, 6, 0, s);  // パルス数表示
 lcd.setCursor(0, 0) ;
 lcd.print(s) ;
 temp = count / 16.0 - 50.0;  // 温度表示
 dtostrf(temp, 6, 1, s);
 lcd.setCursor(0, 1) ;
 lcd.print(s) ;
 lcd.print("c") ;
 pinMode(5, INPUT); // D5をオフ(フロート状態)にしてLMT01-no.1をストップ
 delay(1);

 pinMode(6, OUTPUT);
 digitalWrite(6, 1); // D6をオンにしてLMT01-no.2をスタート
 delay(1);
 countpulse();
 dtostrf(count, 6, 0, s);  // パルス数表示
 lcd.setCursor(8, 0) ;
 lcd.print(s) ;
 temp = count / 16.0 - 50.0;  // 温度表示
 dtostrf(temp, 6, 1, s);
 lcd.setCursor(8, 1) ;
 lcd.print(s) ;
 lcd.print("c") ;
 pinMode(6, INPUT); // D6をオフ(フロート状態)にしてLMT01-no.2をストップ
 delay(1);
}

void initComp()
{
 cbi(ACSR, ACD);   // Analog Comparator Disable : コンパレータを使う設定にする
 sbi(ACSR, ACBG);  // Analog Comparator Bandgap Select : 内部基準電圧(1.1V)を使う設定にする
 sbi(ACSR, ACIE);  // Analog Comparator Interrupt Enable : コンパレータ割り込みを許可する
 cbi(ACSR, ACIC);  // Analog Comparator Input Capture Enable
 sbi(ACSR, ACIS1); // Analog Comparator Interrupt Mode Select1 : コンパレータの立下りで割り込み設定
 cbi(ACSR, ACIS0); // Analog Comparator Interrupt Mode Select0 : コンパレータの立下りで割り込み設定
 sbi(PRR, PRADC);  // オリジナルではcbi(PRR0, PRADC);だったがエラーになった。
 cbi(ADCSRB, ACME);  //Analog Comparator Multiplexer Enable : コンパレータ反転入力をAIN1にする
}

void countpulse()
{
 count = 0;
 LASTcount = 0;
 while (count == 0) {}
 if (count != 0) {
   // カウンタがゼロではない場合、つまりカウント中なら
   while (count != LASTcount) {     // もし数値が変わっていたらまだ測定中なので以下を繰り返す
     LASTcount = count;             // 次回の比較用に値を保存
     delay(1);                      // ちょっと待つ
   }
 }
}

ISR(ANALOG_COMP_vect) {
 count++;
}

関連記事
スポンサーサイト

コメント

コメントの投稿

管理者にだけ表示を許可する

トラックバック

この記事へのトラックバックURL
http://edycube.blog2.fc2.com/tb.php/872-105f52b3

 | HOME | 

文字サイズの変更

プロフィール

edy

最新記事一覧(サムネイル画像付き)

MT3608モジュールのテスト Apr 30, 2017
BME280モジュールを使った温度・湿度・気圧計(2)DSO Shellを使って動作電流を測る Apr 23, 2017
BME280モジュールを使った温度・湿度・気圧計 Apr 23, 2017
DSO Shell(2)電源 Apr 16, 2017
小学一年生5月号付録 ドラえもん こえピアノ Apr 14, 2017
DSO Shell(1) Apr 13, 2017
非接触温度センサMLX90614を試す(6)プラケースに入れる Apr 03, 2017
アナログフィルタ Mar 28, 2017
非接触温度センサMLX90614を試す(5)Arduino pro miniを使ってみる Mar 19, 2017
非接触温度センサMLX90614を試す(4)耳内温を測ってみる。 Mar 12, 2017

全記事表示リンク

全ての記事を表示する

ブログリンク

リンク

このブログをリンクに追加する

月別アーカイブ

04  03  02  01  12  11  10  09  08  07  06  05  04  03  02  01  12  11  10  09  08  07  06  05  04  03  02  01  12  11  10  09  08  07  06  05  04  03  02  12  11  10  09  07  05  04  03  04  03  01  12  11  10  08  07  06  05  03  02  01  12  11  10  09  08  07  06  05  04  03  02  01  12  11  10  09  08  07  06  05  04  02  01  12  10  09  08  07  06  05  04  03  02  01  12  11  10  09  08  07  06  05  03  02  01  12  11  10  09  08  07  06  05  04  03  02  01  12  10  09  08  07  06  05  04  03  02  01 

カテゴリ

プログラミング (0)
freescale (1)
AVR (3)
テルミン (16)
緊急警報放送 (3)
78K (1)
PSoC (295)
地上デジタル放送 (2)
電子工作 (391)
HX711 (2)
ACS712 (6)
数学 (6)
パソコン (12)
PLC (14)
未分類 (39)
ブログ関係 (20)
スカイプ (37)
ロボット (1)
LTSpice (8)
OCXO (0)
arduino (28)
maxima (1)
フランクリン発振回路 (3)
GPS (3)
DTMF (1)
Linux (1)
KOMAINO (7)

タグリスト

最近のコメント

最近のトラックバック

メールフォーム

名前:
メール:
件名:
本文:

検索フォーム

アクセス

RSSリンクの表示

フリーエリア

FC2Ad

まとめ

Template by たけやん